FactoryTalk View SE looping through ActiveX controls

I've got several ListBoxes that I want to perform the same function on. From my searches, you can accomplish this in VBA by using a FOR loop, but only on the controls within a form. Rockwell knoweldgebase recommends to avoid using forms at all costs.

I've tried using a FOR loop on the ListBoxes in Me.ActiveDisplay, and I've also tried creating a group of my ListBoxes, exposing it to VBA, and trying a FOR loop on Me.MyListBoxGroup but the error is always "Object doesn't support this property or method."

Anyone ever do this or is it impossible without a form?

Yes, you probably can... define a variable as an element, say objElm, then do a loop for each objElm in activedisplay.elements. All of the list boxes have to be exposed to VBA control. You can look at objElm.name to decide which list Box you are on; it helps to have them named consistently in Object Explorer.

Give it a shot, I’ll try to post some of my vba tomorrow. There might be some trick if the objects are nested.

Here I'm just referencing the list box (ComboBox) directly:

in the ThisDisplay module
Call LoadTapRcv(Me.cmbTapRcv1, 1, 7, 1)

then the subroutine:

Private Sub LoadTapRcv(byval cmbCurr as MSForms.ComboBox, dblStart as double, dblEnd as Double, dblIncr as double)
on error goto proc_exit

Dim dblCurr as double

with cmbCurr
.Clear
for dblcurr = dblstart to dblend step dblIncr
.AddItem dblcurr
next dblcurr
.ListRows = .Listcount
end with

Proc_Exit:

exit sub

end sub

Another one, finding elements by name to load the list:

Dim elmCurr As DisplayClient.Element

Dim arrReasons As Variant

Dim intRow As Integer
Dim intCol As Integer

arrReasons = Array(" ", "Tap", "Burn", "Matte", "Cleaning", _
"Running", "Spill", "Vent", "Crane", "Slag")

For intRow = 1 To DispTapRows
For intCol = 1 To 3
Set elmCurr = Me.FindElement("cmbReason" & Format(intRow, "00") & CStr(intCol))
Call LoadDelayReason(elmCurr, arrReasons, intRow, intCol)
Next intCol
Next intRow


The loaddelayreason routine is just a variant on the first one. With the consistently named objects on the display, I can easily loop through and change all the controls I want. I misremembered my code, I ended up referencing all elements directly. I did have a recursive module to find the element, didn't need it:

Public Function GetElement(ByVal elmBase As DisplayClient.Elements, ByVal strCtl As String) As DisplayClient.Element

Dim elmCurr As Object

For Each elmCurr In elmBase
If TypeName(elmCurr) = "IGroup" Then
Set GetElement = GetElement(elmCurr.Elements, strCtl)
Else
If elmCurr.Name = strCtl Then
Set GetElement = elmCurr
End If
End If
If Not GetElement Is Nothing Then
Exit For
End If
Next elmCurr

End Function

You would call it as:

Set elmNeeded = GetElement(ThisDisplay.Elements, "lstMyList")

and it would return the lstMyList object into elmNeeded.

Art, thanks for your help. Fellow Arizonan here, by the way. That last bit where you use the function is similar to what I was attempting. I tried what you suggested and defined a function then called the function, but I still get the "Object doesn't support this property or method" error, and I'm not sure why.

If you step through the program using the F8 key, which line is it balking at? If you have your display client configured for debugging; a separate debug window will pop up showing the VBA, probably stopped right where you are getting the error.