How can I delete values in an db (step7)

Riddick · May 22, 2010

Hi, I want to delete the content of a db (STEP7) where I don't know the length of. In STL there is a command 'DBLG' where you can read out the lenght of a db, is there a way in SCL to determine the length of a db or is there another way to do this ? Thanx in advance

TurpoUrpo · May 22, 2010

You can make function that opens db and uses dblg to check for its lenght and return it. Call that from scl program. Or use SFC 24 from scl program.

bara_hence · May 22, 2010

There is an SFC Test_DB or something that returns the lenght use that

Saw that TurpoUrpo already had posted that.. SFC24..

Riddick · May 22, 2010

Thanks four your answers, I guess there is no direct way to do it in scl, I thougth that maybe I could use the AT command!

Riddick · May 22, 2010

Thanks for your answers, I guess there is no direct way to do it in scl, I thougth that maybe I could use the AT command!

L D[AR2P#0.0] · May 22, 2010

Call this function:

Code:

FUNCTION FC88:VOID
//Determine size of db in bytes and fill it with zeros
VAR_INPUT
DBNumber:WORD;
end_var
VAR_TEMP
iSFC21Return:INT;
iSFC24Return:INT;
Zero:BYTE;
BLK:ANY;
dbLength:WORD;
WriteProtect:BOOL;
BlockFill AT BLK: STRUCT
    id:WORD;
    Count:WORD;
    DB:WORD;
    Area:DWORD;
    END_STRUCT;
END_VAR; 
Zero:=0;
iSFC24Return:=SFC24(DB_Number:=DBNumber,DB_Length:=DBLength, WRITE_PROT:=WriteProtect);
BlockFill.id:=w#16#1002;
BlockFill.Count:=DBLength;
BlockFill.DB:=DBNumber;
BlockFill.Area:=dw#16#84000000;
iSFC21Return:=SFC21(BVAL := Zero,BLK := BLK);
END_FUNCTION

Riddick · May 23, 2010

Thanks for your help but the program still uses SFC24

!

L D[AR2P#0.0] · May 23, 2010

Do you want this done in SCL without calling SFC24 ? If so why ?

Here's one implementation.

Code:

FUNCTION FC88:VOID
//Determine size of db in bytes and fill it with zeros
VAR_INPUT
DBNumber:WORD;
end_var
VAR_TEMP
iSFC21Return:INT;
iSFC24Return:INT;
Zero:BYTE;
BLK:ANY;
dbLength:WORD;
WriteProtect:BOOL;
BlockFill AT BLK: STRUCT
    id:WORD;
    Count:int;
    DB:WORD;
    Area:DWORD;
END_STRUCT;
HighSearch:INT;
LowSearch:int;
Search:int;
END_VAR; 
Zero:=0;
BlockFill.id:=w#16#1002;
BlockFill.DB:=DBNumber;
BlockFill.Area:=dw#16#84000000;
LowSearch:=0;
Highsearch:=32767;
WHILE (HighSearch - LowSearch)>1 DO
Search:= (Lowsearch+Highsearch)/2;    
BlockFill.Count:=Search;        
iSFC21Return:=SFC21(BVAL := Zero,BLK := BLK);
IF iSFC21Return = 0 THEN Lowsearch:=Search; ELSE HighSearch:=Search;END_IF;
END_WHILE;
END_FUNCTION

Riddick · May 23, 2010

Because even SFC24 is using an certain call to this db in a protected language, don't you think it's cool to just do it in scl itselfs? I think I can use the command AT but I don't know how. It isn't that important but I was just wondering if there were other way's to do this.

TurpoUrpo · May 23, 2010

What you mean by protected language? what does it even matter, its os implemented function, that sfc 24 is just interface for it.

What about the suggestion of making fc that uses dblg to check for lenght and returns it? what is prob with it?

I'll look at how db behaves with ANY.

Riddick · May 24, 2010

You are right it doesn't matter at all, thanks for your help

How can I delete values in an db (step7)

Riddick

Member

TurpoUrpo

Lifetime Supporting Member

bara_hence

Member

Riddick

Member

Riddick

Member

L D[AR2P#0.0]

Lifetime Supporting Member

Riddick

Member

L D[AR2P#0.0]

Lifetime Supporting Member

Riddick

Member

TurpoUrpo

Lifetime Supporting Member

Riddick

Member

Similar Topics