Simatic S7-STL Bubblesort funciton code

FUNCTION FC123: VOID
// BUBBLESORT IN ARRAY
VAR_INPUT
TRIG: BOOL;
Data_In: ARRAY[1..10] OF INT;   
END_VAR    
VAR_OUTPUT
Data_Out: ARRAY[1..10] OF INT;
END_VAR    
VAR_IN_OUT
Flank_Mem: BOOL;    
END_VAR    
VAR_TEMP
i: INT;
v: BOOL;
j: INT;
Temp: INT;
Data: ARRAY[1..10] OF INT; 
Trig_Flank: BOOL;
END_VAR

BEGIN
Trig_Flank:= TRIG AND (NOT Flank_Mem); // Positieve flank op TRIG bit
IF Trig_Flank THEN
  FOR i := 1 TO 10 DO
    Data [i]:= Data_In[i] ;            // Data_In naar tijdelijke Data verzenden voor verwerking
  END_FOR;     
    i := 1;
    v := True;        
    WHILE i < 10 AND v = True DO
        v := False;
        j := 1;
        WHILE j <= 10 - i DO
            IF Data[j] > Data[j + 1] THEN
                Temp := Data[j];
                Data[j] := Data[j + 1];
                Data[j + 1] := Temp;
                v := True;
            END_IF;
            j := j + 1;
        END_WHILE;
        i := i + 1;
    END_WHILE;
   
    FOR i := 1 TO 10 DO                // Gesorteerde tijdelijke Data verzenden naar Data_Out
    Data_Out [i]:= Data[i] ;
    END_FOR;
END_IF; 
Flank_Mem:= TRIG;                      // Flank wegschrijven
END_FUNCTION

miami_vice said:

Hi to everybody,

I'm new in the Simatic S7 world......
I've searched in this forum for some post about how realize in STL code a bubblesort function, but sorry I don't have success for realize the routine.

So I need to realize the follow code in FC routine.
In the DB10 are written 100 word in INT format, on an event eg.m100.0 the data in the DB10 must be sorted in DB11 having same size and data format.....

Someone can supply the file project or code to make the FC routine??

Thanks Thanks a lot

Click to expand...

miami_vice said:

Thanks a lot Gerry.

I have not the SCL tool programming installed in my S7.
So when I open the routine function FC123, suppose that the original source code is compiled automatically in STL, but really the code is very big respect the SCL.

As I have told in my previous message I'm new in S7 world, but I think that during the compile operation for convert the code from SCL to STL, S7 use many instruction and the program is not very efficient about the memory used and is not very clear to understand (like spaghetti plate) especially for me don't have a lot esperience in S7.

Maybe is possible rewrite better the code in STL respect the code generated from SCL to STL, but maybe this is only my personal opinion.

Anyway your cooperation is very appreciated.

Click to expand...

L D[AR2 said:

Here is Combo's SCL code re-written in STL using DB10&11 for the data using the evolutionary biodegradable compiler

Code:

FUNCTION FC 124 : VOID
TITLE =
VERSION : 0.1
 
 
VAR_INPUT
  TRIG : BOOL ;    
END_VAR
VAR_IN_OUT
  Flank_Mem : BOOL ;    
END_VAR
VAR_TEMP
  ii : INT ;    
  v : BOOL ;    
  j : INT ;    
  Temp : INT ;    
  Trig_Flank : BOOL ;    
  iSFC20Return : INT ;    
END_VAR
BEGIN
NETWORK
TITLE =
//
//
      A     #TRIG; 
      FP    #Flank_Mem; 
      =     #Trig_Flank; 
      A     #Trig_Flank; 
      JCN   exit; 
      CALL SFC   20 (
           SRCBLK                   := P#DB10.DBX 0.0 INT 100,
           RET_VAL                  := #iSFC20Return,
           DSTBLK                   := P#DB11.DBX 0.0 INT 100);
      L     1; 
      T     #ii; // ii=1
      SET   ; 
      S     #v; // v = True
whl1: NOP   0; 
      A(    ; // while ii < 100 and v = true
      L     #ii; 
      L     100; 
      <I    ; 
      )     ; 
      A     #v; 
      JCN   enw1; // do
      R     #v; // v = false
      L     1; // j = 1
      T     #j; 
whl2: NOP   0; //While j <= 100 - ii
      L     100; 
      L     #ii; 
      -I    ; 
      L     #j; 
      TAK   ; 
      <=I   ; 
      JCN   enw2; 
      OPN   DB    11; // do
      L     #j; 
      +     -1; 
      SLD   4; 
      LAR1  ; 
      L     DBW [AR1,P#0.0]; // if Data[j] > Data[j+1]
      L     DBW [AR1,P#2.0]; 
      >I    ; 
      JCN   eif1; 
      TAK   ; // then Begin 
      T     #Temp; //       Temp = Data[j]
      L     DBW [AR1,P#2.0]; 
      T     DBW [AR1,P#0.0]; //       Data[j+1] = Data[j]
      L     #Temp; 
      T     DBW [AR1,P#2.0]; //       Data[j] = Temp
      SET   ; 
      S     #v; //       v = true
eif1: NOP   0; //      end
      L     #j; // j = j + 1
      +     1; 
      T     #j; 
      JU    whl2; 
enw2: NOP   0; // endwhile
 
      L     #ii; // ii=ii+1
      +     1; 
      T     #ii; 
      JU    whl1; 
enw1: NOP   0; //endwhile
 
exit: NOP   0; 
 
END_FUNCTION

Click to expand...

L D[AR2 said:

Here is Combo's SCL code re-written in STL using DB10&11 for the data using the evolutionary biodegradable compiler

Click to expand...