Siemens compare using AR1 and AR2

JOLTRON · Jun 2, 2011

I am looking for some advice on this FC I just wrote. I have trace numbers that are constantly moved and want to verify that they match. They are always 10 bytes long stored as CHAR. This is my first attempt at using AR1 and AR2. Is this the most efficient way to do this? Also do I need to save AR1 and AR2 and the restore them at the end of the FC? I remeber hearing this but can't remeber how or why.

Here it is, what do you think?

Code:

FUNCTION "CompareTraceNum" : BOOL
TITLE =Copy block with a block move
{ S7_language := '7(1) Deutsch (Deutschland)  28.05.2007  14:31:12' }
NAME : CopyByte
VERSION : 0.1
 
VAR_INPUT
  DB_Src_1 : INT ; 
  ByteSrc_1 : INT ; 
  DB_Src_2 : INT ; 
  ByteSrc_2 : INT ; 
  Bytes : INT ; 
END_VAR
VAR_TEMP
  tempDB_Src_1 : INT ; 
  tempDB_Src_2 : INT ; 
  tempSrc_1_pntr : DWORD ; 
  tempSrc_2_pntr : DWORD ; 
END_VAR
BEGIN
NETWORK
TITLE =Copy data
//Create Temp DB numbers so they can be used with the OPN command 
      L     #DB_Src_1; 
      T     #tempDB_Src_1; 
      L     #DB_Src_2; 
      T     #tempDB_Src_2; 
 
//Create pointers for base of compare
      L     P#DBX 0.0; //Create pointer for source 1 byte
      L     #ByteSrc_1; 
      SLD   3; 
      +D    ; 
      LAR1  ; 
      L     P#DBX 0.0; //Create pointer for source 2 byte
      L     #ByteSrc_2; 
      SLD   3; 
      +D    ; 
      LAR2  ; 
//compare 1st DWord of Trace
      OPN   DB [#tempDB_Src_1]; 
      L     D [AR1,P#0.0]; 
      OPN   DB [#tempDB_Src_2]; 
      L     D [AR2,P#0.0]; 
      ==D   ; 
      JCN   NOK; 
//compare 2nd DWord of Trace
      OPN   DB [#tempDB_Src_1]; 
      L     D [AR1,P#4.0]; 
      OPN   DB [#tempDB_Src_2]; 
      L     D [AR2,P#4.0]; 
      ==D   ; 
      JCN   NOK; 
//compare last Word of Trace
      OPN   DB [#tempDB_Src_1]; 
      L     W [AR1,P#8.0]; 
      OPN   DB [#tempDB_Src_2]; 
      L     W [AR2,P#8.0]; 
      ==D   ; 
      JCN   NOK; 
//If trace matches set the return value TRUE
      SET   ; 
      =     #RET_VAL; 
      BEU   ; 
NOK:  CLR   ; 
      =     #RET_VAL; 
//SET and SAVE so ENO is always enabled
      SET   ; 
      SAVE  ; 
 
 
 
END_FUNCTION

L D[AR2P#0.0] · Jun 2, 2011

I can save a few instructions, but that is being picky.

If you call this block from an FC/FB and you are using AR1 in a loop in the calling FC/FB, then your FC will have to save and restore AR1

If you call this block from an FB, the editor will automatically save AR2 for you before calling the block and restore it after returning from the block.

Code:

FUNCTION FC 1 : BOOL
TITLE =Copy block with a block move
{ S7_language := '7(1) Deutsch (Deutschland)  28.05.2007  14:31:12' }
NAME : CopyByte
VERSION : 0.1


VAR_INPUT
  DB_Src_1 : INT ;    
  ByteSrc_1 : INT ;    
  DB_Src_2 : INT ;    
  ByteSrc_2 : INT ;    
  Bytes : INT ;    
END_VAR
VAR_TEMP
  tempDB_Src_1 : INT ;    
  tempDB_Src_2 : INT ;    
  tempSrc_1_pntr : DWORD ;    
  tempSrc_2_pntr : DWORD ;    
END_VAR
BEGIN
NETWORK
TITLE =Copy data
//Create Temp DB numbers so they can be used with the OPN command 
      L     #DB_Src_1; 
      T     #tempDB_Src_1; 
      L     #DB_Src_2; 
      T     #tempDB_Src_2; 

//Create pointers for base of compare
      L     #ByteSrc_1; 
      SLD   3; 
      LAR1  ; 
      L     #ByteSrc_2; 
      SLD   3; 
      LAR2  ; 
//compare 1st DWord of Trace
      OPN   DB [#tempDB_Src_1]; 
      L     DBD [AR1,P#0.0]; 
      OPN   DB [#tempDB_Src_2]; 
      L     DBD [AR2,P#0.0]; 
      ==D   ; 
      JCN   NOK; 
//compare 2nd DWord of Trace
      L     DBD [AR2,P#4.0]; 
      OPN   DB [#tempDB_Src_1]; 
      L     DBD [AR1,P#4.0]; 
      ==D   ; 
      JCN   NOK; 
//compare last Word of Trace
      L     DBW [AR1,P#8.0]; 
      OPN   DB [#tempDB_Src_2]; 
      L     DBW [AR2,P#8.0]; 
      ==D   ; 
      JCN   NOK; 
//If trace matches set the return value TRUE
      SET   ; 
      =     #RET_VAL; 
      BEU   ; 
NOK:  CLR   ; 
      =     #RET_VAL; 
//SET and SAVE so ENO is always enabled
      SET   ; 
      SAVE  ; 



END_FUNCTION

JOLTRON · Jun 2, 2011

Very clever! Thanks for looking it over

So when you use the Address Register you don't need to build the pointer prior to it. I guess that is taken care of here L DBD [AR2,P#0.0];

I guess I don't fully understand this:

If you call this block from an FC/FB and you are using AR1 in a loop in the calling FC/FB, then your FC will have to save and restore AR1

Do you mean using AR1 to indirectly call FC's and FB's?

Is it considred good practice to save and restore the the AR's whenever they are used?

Is it as simple as:
LAR1
T TempDW
[do work in FC]
L TempDW
T AR1

L D[AR2P#0.0] · Jun 2, 2011

Yes, thats the code that the editor inserts prior to calling an FC from an FB but it saves AR2

L D[AR2P#0.0] · Jun 2, 2011

JOLTRON said:
Do you mean using AR1 to indirectly call FC's and FB's?

No, simply that if you are using AR1 and then call another FC that uses AR1 you will have to save/restore AR1 as per the code above.

KalleOlsen · Jun 2, 2011

JOLTRON said:
Is it as simple as:
TAR1
T TempDW
[do work in FC]
L TempDW
LAR1

This works better!

Kalle

L D[AR2P#0.0] · Jun 2, 2011

Good spot Kalle, I can save a couple of lines

Code:

      TAR1  #dwTemp
      [do work in FC]
      LAR1  #dwTemp

JOLTRON · Jun 3, 2011

Thanks alot guys!!!

Siemens compare using AR1 and AR2

JOLTRON

Lifetime Supporting Member

L D[AR2P#0.0]

Lifetime Supporting Member

JOLTRON

Lifetime Supporting Member

L D[AR2P#0.0]

Lifetime Supporting Member

L D[AR2P#0.0]

Lifetime Supporting Member

KalleOlsen

Member

L D[AR2P#0.0]

Lifetime Supporting Member

JOLTRON

Lifetime Supporting Member

Similar Topics