Siemens S7 Sort Code

SmooshBall · Mar 13, 2014

Hello,

I some help to make an SCL code for sorting of 4 DINTS inn.

The plan is to have 4x Motors, where the total hours comes in to a block which sorts out which of the motors got lowest running hours.
Out of the block I want 4x INT's named Y_Dev1, Y_Dev2 etc.
The block should place the numbers 1-4 on them, where 1 is lowest.

Finding highest and lowest number isn't any problem, but the two inn middle I need some help with if some got the time

Eric Nelson · Mar 13, 2014

Since you only have 4, a quick solution might be to just reuse the same process you're already using to determine #1 and #4. If you process the two leftover ones, the lowest value becomes #2, and the highest becomes #3.

-Eric

boneless · Mar 13, 2014

So you are feeding 4x DINT into a function. Say IN_1 .. IN_4.

The function returns 4x INT Y_Dev1 .. Y_Dev4.

If IN_3 has the highest value of the 4 inputs, Y_Dev3 will return a 4.
If IN_1 has the second highest value of the 4 inputs, Y_Dev1 will return a 3.
etc.

Is that right?

SmooshBall · Mar 13, 2014

boneless said:
So you are feeding 4x DINT into a function. Say IN_1 .. IN_4.

The function returns 4x INT Y_Dev1 .. Y_Dev4.

If IN_3 has the highest value of the 4 inputs, Y_Dev3 will return a 4.
If IN_1 has the second highest value of the 4 inputs, Y_Dev1 will return a 3.
etc.

Is that right?

Yeah! I'm trying to mix IF command with max /min functions now.
Trying to use fewest lines as possible.
But any advice are gladly welcome!

L D[AR2P#0.0] · Mar 13, 2014

Here's one implementation. (Not attempted to use the fewest lines possible as that request came later)

Code:

FUNCTION_BLOCK FB97
VAR_INPUT
    diMotor1Hours:DINT;
    diMotor2Hours:DINT;
    diMotor3Hours:DINT;
    diMotor4hours:DINT;
END_VAR

VAR_OUTPUT
    Y_dev1:INT;
    Y_dev2:INT;
    Y_dev3:INT;
    Y_dev4:INT;

END_VAR

VAR
Y_Dev:INT;
iLoop:INT;
adiMotor:ARRAY[1..4] OF DINT;
diMotor:DINT;
END_VAR
BEGIN

adiMotor[1]:=diMotor1Hours;
adiMotor[2]:=diMotor2Hours;
adiMotor[3]:=diMotor3Hours;
adiMotor[4]:=diMotor4Hours;
//assume order
Y_Dev1:=1;
Y_Dev2:=2;
Y_Dev3:=3;
Y_Dev4:=4;

FOR iLoop:=1 TO 3 DO 
 IF adiMotor[2] < adiMotor[1] THEN 
   Y_Dev:=Y_Dev1;
   Y_Dev1:=Y_Dev2;
   Y_Dev2:=Y_Dev;
   diMotor:=adiMotor[1];
   adiMotor[1]:=adiMotor[2];
   adiMotor[2]:=diMotor;
 END_IF;
    
 IF adiMotor[3] < adiMotor[2] THEN 
   Y_Dev:=Y_Dev2;
   Y_Dev2:=Y_Dev3;
   Y_Dev3:=Y_Dev;
   diMotor:=adiMotor[2];
   adiMotor[2]:=adiMotor[3];
   adiMotor[3]:=diMotor;

 END_IF;

 IF adiMotor[4] < adiMotor[3] THEN 
   Y_Dev:=Y_Dev3;
   Y_Dev3:=Y_Dev4;
   Y_Dev4:=Y_Dev;
   diMotor:=adiMotor[3];
   adiMotor[3]:=adiMotor[4];
   adiMotor[4]:=diMotor;

 END_IF;
END_FOR;
end_function_Block

SmooshBall · Mar 13, 2014

Thank you for all your help i really appreciate it!
I'm going to try to make one myself now and make it more complicated.

L D[AR2P#0.0] · Mar 13, 2014

Shorter version

Code:

FUNCTION_BLOCK FB97
VAR_INPUT
    diMotor1Hours:DINT;
    diMotor2Hours:DINT;
    diMotor3Hours:DINT;
    diMotor4hours:DINT;
END_VAR

VAR_OUTPUT
    Y_dev1:INT;
    Y_dev2:INT;
    Y_dev3:INT;
    Y_dev4:INT;

END_VAR

VAR
Y_Dev:INT;
iLoop:INT;
oLoop:INT;
adiMotor:ARRAY[1..4] OF DINT;
aY_Dev:ARRAY[1..4] OF INT;
diMotor:DINT;
END_VAR
BEGIN

adiMotor[1]:=diMotor1Hours;
adiMotor[2]:=diMotor2Hours;
adiMotor[3]:=diMotor3Hours;
adiMotor[4]:=diMotor4Hours;
//assume order
FOR iLoop:=1 TO 4 do
aY_Dev[iLoop]:=iLoop;
END_FOR;

FOR iLoop:=1 TO 3 DO 
 FOR oLoop:=1 TO 3 DO
  IF adiMotor[oLoop+1] < adiMotor[oLoop] THEN 
   Y_Dev:=aY_Dev[oLoop];
   aY_Dev[oLoop]:=aY_Dev[oLoop+1];
   aY_Dev[oLoop+1]:=Y_Dev;
   diMotor:=adiMotor[oLoop];
   adiMotor[oLoop]:=adiMotor[oLoop+1];
   adiMotor[oLoop+1]:=diMotor;
  END_IF;
 END_FOR;    
END_FOR;
Y_dev1:=aY_dev[1];
Y_dev2:=aY_dev[2];
Y_dev3:=aY_dev[3];
Y_dev4:=aY_dev[4];

END_FUNCTION_BLOCK

Siemens S7 Sort Code

SmooshBall

Member

Eric Nelson

Lifetime Supporting Member + Moderator

boneless

Lifetime Supporting Member + Moderator

SmooshBall

Member

L D[AR2P#0.0]

Lifetime Supporting Member

SmooshBall

Member

L D[AR2P#0.0]

Lifetime Supporting Member

Similar Topics