DB to DB in S7 (any pointer)

Any Pointer, what a beast...

I wrote this:

L P##Bron
LAR1
L P##Doel
LAR2
L B#16#10
T LB [AR1,P#0.0]
T LB [AR2,P#0.0]
L B#16#2
T LB [AR1,P#1.0]
T LB [AR2,P#1.0]
L #Lengte_Bytes
T LW [AR1,P#2.0]
T LW [AR2,P#2.0]
L #BronDB
T LW [AR1,P#4.0]
L #DoelDB
T LW [AR2,P#4.0]
L #BronByte
SLD 3
L DW#16#84000000
OW
T LW [AR1,P#6.0]
L #DoelByte
SLD 3
L DW#16#84000000
OW
T LW [AR2,P#6.0]


CALL SFC 20
SRCBLK :=#Bron
RET_VAL:=#RET
DSTBLK :=#Doel



I entered DB30 As Bron (Source) and DB40 as Doel (destination DB).

But the DB30 data is not given to DB40 ??

ANy ideas why ?

Click to expand...

I haven't run this code, so the corrections are just from eyeballing. Why not post the whole FC in source code - then we don't have to guess what the variable types are.

Hey

I had to send to DW, not LW, that's the good correction you gave, thanks:

source:

FUNCTION "DB TO DB" : VOID
TITLE =DB TO DB
VERSION : 0.1

VAR_INPUT
BronDB : INT ;
BronByte : INT ;
DoelDB : INT ;
DoelByte : INT ;
Lengte_Bytes : INT ;
END_VAR
VAR_OUTPUT
Fout : BOOL ;
END_VAR
VAR_TEMP
Bron : ANY ;
Doel : ANY ;
RET : INT ;
END_VAR
BEGIN
NETWORK
TITLE =Samenstelling Any Pointer

L P##Bron;
LAR1 ;
L P##Doel;
LAR2 ;
L B#16#10;
T LB [AR1,P#0.0];
T LB [AR2,P#0.0];
L B#16#2;
T LB [AR1,P#1.0];
T LB [AR2,P#1.0];
L #Lengte_Bytes;
T LW [AR1,P#2.0];
T LW [AR2,P#2.0];
L #BronDB;
T LW [AR1,P#4.0];
L #DoelDB;
T LW [AR2,P#4.0];
L #BronByte;
SLD 3;
L DW#16#84000000;
OW ;
T LD [AR1,P#6.0];
L #DoelByte;
SLD 3;
L DW#16#84000000;
OW ;
T LD [AR2,P#6.0];
NETWORK
TITLE =Transfereer Data van Bron naar Doel

CALL "BLKMOV" (
SRCBLK := #Bron,
RET_VAL := #RET,
DSTBLK := #Doel);
END_FUNCTION

The area pointer uses the bottom 19 bits for the byte/bit address. By using the OW instruction, you will only incorporate the bottom 16 bits of the byte pointer address and thus limit the start byte for your DB to DBB8191. If you try to access DBB8192 it will actually access DBB0.

..;

But DBB8191 as a startbyte ? isn't that a lot of bytes in a DB allready ?

But you're right, it's not 100% safe what I'm doing

L D[AR2 said:

The area pointer uses the bottom 19 bits for the byte/bit address. By using the OW instruction, you will only incorporate the bottom 16 bits of the byte pointer address and thus limit the start byte for your DB to DBB8191. If you try to access DBB8192 it will actually access DBB0.

Click to expand...

[QUOTE='L D[AR2,P#0.0]By using the OW instruction, you will only incorporate the bottom 16 bits of the byte pointer address..[/QUOTE]

I think Simon was 'pointing' you towards a modification....

Combo, you should definitely be using a dint for the byte address. Otherwise, sooner or later you will be bitten by a dynamically generated pointer.

Also, another tip: I always "OR" the address with a variable in pointer format. It just makes it a little more clear for others that read your code in case they aren't familiar with the hex equivelents. For instance:


L LD[AR1,P#6.0]
L P#DIX0.0
OD
T LD[AR1,P#6.0]

That would be the same as ORing with a HEX 85000000. This works for any pointer type (P#M0.0, P#Q0.0, etc).

edit. Saw that Simon implied the same thing above.

..

So OD instead of OW
Okay

Thanks a lot

S7Guy said:

Combo, you should definitely be using a dint for the byte address. Otherwise, sooner or later you will be bitten by a dynamically generated pointer.

Also, another tip: I always "OR" the address with a variable in pointer format. It just makes it a little more clear for others that read your code in case they aren't familiar with the hex equivelents. For instance:


L LD[AR1,P#6.0]
L P#DIX0.0
OD
T LD[AR1,P#6.0]

That would be the same as ORing with a HEX 85000000. This works for any pointer type (P#M0.0, P#Q0.0, etc).

edit. Saw that Simon implied the same thing above.

Click to expand...