Blkmov - Indirect

leflek · May 29, 2009

Hello,

I have created the following code in step7

OPN "L1_Stage"
L P#810.0
T #Temp1
L 405
Stag: T #Count1
L #Temp1
L P#2.0
-D
T #Temp2
L DBW [#Temp2]
T DBW [#Temp1]
L #Temp2
T #Temp1
L #Count1
LOOP Stag

With this code i transfer all values in datablock "L1_Stage"
one position down and later in my program i put a new value in
the first position of this datablock. The datablock "L1_Stage"
contains int values.

I want to do the same thing with the following data block

Address Name Type
+0.0 C1 STRING[20]
+22.0 C2 STRING[20]
+44.0 C3 STRING[20]
+66.0 C4 STRING[20]
+88.0 C5 STRING[20]
+110.0 C6 STRING[20]
+132.0 C7 STRING[20]
+154.0 C8 STRING[20]
+176.0 C9 STRING[20]
+198.0 C10 STRING[20]

I have used the BLKMOV function because i can not use load
transfer instruction with data type string and it works

CALL "BLKMOV"
SRCBLK :="L1_ProfilCode".C1
RET_VAL:=#ret
DSTBLK :="L1_ProfilCode".C2

My question is how can i can use indirect addressing with the
funtion BLKMOV, so that i can use a loop to transfer all values of my datablock one position down.

Thanks

Lefteris

manmeetvirdi · May 29, 2009

Hi
Well you can use the format of parameter type ANY, I think.
Just type ANY in help of S7 and the appropriate link will come up.
Code is also there under the heading "Using the Parameter Type ANY".
Something like this

Code:

   L     P#DBX 198.0
      T     #temp1
      L     10
stag: T     #count1
      L     #temp1
      L     P#22.0
      -D    
      T     #temp2


      LAR1  P##Source

      L     B#16#10
      T     LB [AR1,P#0.0]

      L     B#16#13
      T     LB [AR1,P#1.0]

      L     1
      T     LW [AR1,P#2.0]

      L     14     //your DB No.
      T     LW [AR1,P#4.0]

      L     #temp2
      T     LD [AR1,P#6.0]

      LAR1  P##Target

      L     B#16#10
      T     LB [AR1,P#0.0]

      L     B#16#13
      T     LB [AR1,P#1.0]

      L     1
      T     LW [AR1,P#2.0]

      L     14        //your DB No.
      T     LW [AR1,P#4.0]

      L     #temp1
      T     LD [AR1,P#6.0]

      CALL  "BLKMOV"
       SRCBLK :=#source
       RET_VAL:=#temp3
       DSTBLK :=#target

      L     #temp2
      T     #temp1
      L     #count1
      LOOP  stag

Its untested, will come back after testing.

manmeetvirdi · May 29, 2009

Ok w.r.t post#2

Code:

Instead of 
 
 L     B#16#13     //data type string
 T     LB [AR1,P#1.0]

use

  L     B#16#2      // data type byte
  T     LB [AR1,P#1.0]

And instead of 
    L     1          //repetetion factor=1
    T     LW [AR1,P#2.0]

use 

  L     22           // repetetion factor 22 (22 bytes)
  T     LW [AR1,P#2.0]

This seems to work !!

leflek · Jun 2, 2009

Thank you very much. I used the code you send me in your first post

and it works perfectly !!!

Thanks again - you really helped me a lot

Blkmov - Indirect

leflek

Member

manmeetvirdi

Member

manmeetvirdi

Member

leflek

Member

Similar Topics