Read String out of CLX with Excel

[ak0004]

Hi folks

I am trying to read out a couple of strings with this Code

Sub weigher()

rslinx = DDEInitiate("RSLINX", "Mermaid_04")
For i = 0 To 100


'Get the value form the DDE link
weigherdata = DDERequest(rslinx, "Program:ComSock02_TCPClient.History[" & i & "].String_Data.DATA,L1,C1")


'If there is an error, display a message box
If TypeName(Data) = "Error" Then
If MsgBox("Error reading tag ComSock02_TCPClient.History[" & i & "]String_Data.DATA" & _
"Continue with Read?", vbYesNo + vbExclamation, _
"Error") = vbNo Then Exit For
Else



'No error, place data in cell
Cells(2 + i, 1) = weigherdata
End If
Next i

    
    'Terminate the DDE connection
    DDETerminate rslinx
    
End Sub

I am getting only "74" back into excel...?!?!? But when i look into the CLX there is an complete string an no "74"

any idea where i did the misstake?

 

[hill831017]

74 is ASCII code 'G', is there any 'G' in the string?
Then you know what you need to convert from ' weigherdata'

 

[Ben Pugh]

The way that Rockwell's Logix platform stores strings is with a DINT that holds the length of the string and an array of SINTs that contain the characters of the string. In your case String_Data.LEN will contain the length of the string and String_Data.Data will be an array each element which will contain one string character. Your excel code is reading only the first element of the array and displaying its decimal representation. I did some quick experimenting with excel and got it to display a string by dropping the .Data from the end of the string tag, so I would try that.

 

[ak0004]

The way that Rockwell's Logix platform stores strings is with a DINT that holds the length of the string and an array of SINTs that contain the characters of the string. In your case String_Data.LEN will contain the length of the string and String_Data.Data will be an array each element which will contain one string character. Your excel code is reading only the first element of the array and displaying its decimal representation. I did some quick experimenting with excel and got it to display a string by dropping the .Data from the end of the string tag, so I would try that.

Hi Ben, Thanks for this hint! You are right, the .DATA is not necessary.
But I found another misstake, which was not caused by Excel.
In the .LEN there was in every Array element an 0. Because i copied only the .DATA in the programm

So I changed this to the complete String and then it works.

Thanks vor your Help.

For all who want to use the Code, here the final working.

Sub weigher()

rslinx = DDEInitiate("RSLINX", "Mermaid_04") 'after "," this is the DDE Topic
For i = 0 To 99



'>>>Waagenstring<<<

weigherdata = DDERequest(rslinx, "Program:ComSock02_TCPClient.StringHistory[" & i & "]")
'If there is an error, display a message box
If TypeName(Data) = "Error" Then
If MsgBox("Error reading tag ComSock02_TCPClient.History[" & i & "]String_Data.DATA" & _
"Continue with Read?", vbYesNo + vbExclamation, _
"Error") = vbNo Then Exit For
Else
'No error, place data in Row A
Cells(2 + i, 1) = weigherdata
End If

Next i

'Terminate the DDE connection
DDETerminate rslinx 
    
End Sub

 

[radfahrer]

Write String to Logix 5000 (ControlLogix, CompactLogix) using DDE and VBA

AK004,

Thanks for the final code. Was very helpful for me.

For future reference for others. Here is code I used to write a string value. Make sure not to use .Value in your reference to the Excel cell holding your string...in this case Cells(20,1). If you use Cells(20,1).Value to read the string in the cell, the DDEPoke doesn't work. Excel will read the string properly...ie MsgBox(Cells(20,1).Value) displays the text in the cell, but the DDE doesn't work. That was a little tip I learned on another post in the forum.

Also not to confuse people, TEST_STRING_ARR is an array of strings in the Controllogix. Since the strings themselves are arrays of INTs it can get confusing, but for this code you just refer to the string tag itself, no need to drill down to the .LEN or .DATA[] pieces of the string...Rockwell site has a bunch of KB's about strings mentioning those parts of the datatype, but they're not needed for this to work.

Private Sub CommandButton2_Click()
Dim lngDDE_Chan As Long

lngDDE_Chan = DDEInitiate("RSLINX", "SPECTRA_DEV_1") 'after "," this is the DDE Topic

DDEPoke lngDDE_Chan, "TEST_STRING_ARR[0]", Cells(20, 1)
'Terminate the DDE connection
DDETerminate rslinx
End Sub

 

[radfahrer]

Minor code upate

Oops
My terminate command had wrong channel reference. Still worked (not sure why, maybe with only one channel open it defaults to the correct value), but not good programming practice!

Should look like this.

Private Sub CommandButton2_Click()
Dim lngDDE_Chan As Long

lngDDE_Chan = DDEInitiate("RSLINX", "SPECTRA_DEV_1") 'after "," this is the DDE Topic

DDEPoke lngDDE_Chan, "TEST_STRING_ARR[0]", Cells(20, 1)

'Terminate the DDE connection
DDETerminate lngDDE_Chan

End Sub