Siemens S7 Pointer question.

[genesisfm]

Hi,

I'm programming a piece of software to scan the inputs of the PLC.
But i got a problem... First the code:

A #START_TEL <-- Enable BIT to start the LOOP
JC LP
JU END
LP: L P#1.7 <-- OFFSET start counting at ADRESS 1.7 (I 1.7)
T MD 205 <-- The problem (but it only works with a MD)
L 16 <- Scan for 1 word 16bits
NEXT: T #T_MEM1 <-- LOOP
A I [MD 205] <-- Check input
AN #B_MEM1 <- BLOCK when i see a input
JC WRT
JU EXT
WRT: S #B_MEM1 <-- Set BLOCK
L #T_MEM1 <-- LOAD LOOP COUNT
T #OUTPUT <-- TRANSFER the loop count into VAR
EXT: NOP 0
L MD 205
L P#0.1
-D (min 0.1)
T MD 205
L #T_MEM1
LOOP NEXT (LOOP not ended? goto....)
END: NOP 0 (END LOOP)
R #B_MEM1 (Reset BIT mem)

Whats the problem? I want to:
T MD 205 <-- The problem
Transfer that into a local var example: #A_NAME
Like:
L P#1.7
T #A_NAME
L 16 <- Scan for 1 word 16bits
NEXT: T #T_MEM1 <-- LOOP
A I [#A_NAME] <-- Check input
AN #B_MEM1 <- BLOCK when i see a input

But that doesn't work

Ps. #A_NAME = a DWORD
Can some one help me? I want to use a local input to give my function a variable adress.

Thank you!

Best regards Rob

 

[L D[AR2P#0.0]]

I took your code and replaced all MD205's with a_name and it worked for me:

 

[L D[AR2P#0.0]]

NB: a_name is a temporary dword variable.

 

[genesisfm]

NB: a_name is a temporary dword variable.

I forgot something... I want to use a local variable INPUT. And not a TEMP var.
Because i want to made a function that you can use a variable.

CALL FB 10, DB10
INPUT = P#1.0 (and here the offset)

Thank you.

 

[L D[AR2P#0.0]]

If the parameter you are passing is a pointer, you must use indirect addressing to retrieve the pointer. Here's the source code of an example FB. (I've commented out the first few lines so the block runs all the time)

FUNCTION_BLOCK FB 1
TITLE =
VERSION : 0.1

VAR_INPUT
  INPUT : POINTER ; 
END_VAR
VAR_TEMP
  start_tel : BOOL ; 
  T_mem1 : INT ; 
  output : INT ; 
  b_mem1 : BOOL ; 
  a_name : DWORD ; 
END_VAR
BEGIN
NETWORK
TITLE =
//	  A	 #start_tel				  //<-- Enable BIT to start the LOOP
//	  JC	LP
//	  JU	END
	  TAR2  ; 
	  LAR1  P##INPUT; 
	  +AR1  ; 
	  L	 D [AR1,P#2.0]; 
	  T	 #a_name; //<-- The problem (but it only works with a MD)
	  L	 16; //<- Scan for 1 word 16bits
NEXT: T	 #T_mem1; //<-- LOOP
	  A	 I [#a_name]; //<-- Check input
	  AN	#b_mem1; //<- BLOCK when i see a input
	  JC	WRT; 
	  JU	EXT; 
WRT:  S	 #b_mem1; //<-- Set BLOCK
	  L	 #T_mem1; //<-- LOAD LOOP COUNT
	  T	 #output; //<-- TRANSFER the loop count into VAR
EXT:  NOP   0; 
	  L	 #a_name; 
	  L	 P#0.1; 
	  -D	; //(min 0.1)
	  T	 #a_name; 
	  L	 #T_mem1; 
	  LOOP  NEXT; //(LOOP not ended? goto....)
	  NOP   0; //(END LOOP)
	  R	 #b_mem1; //(Reset BIT mem)
END_FUNCTION_BLOCK

Here's the code being monitored:

 

[genesisfm]

Thank you! This is the solution