Siemens S7 Flip-Flop written in SCL. Possible?

[MrTysk]

Hello.
I was looking a bít at the other threads about flip-flops. Thing is I want to make my own FC working as a flip-flop so I don't have to write the same code everytime I need to use one in the program. 1 push on 1 push off.
I was trying to write a positive edge detection in scl with help from the other threads but I can't get the edge detection to work.

All help how to set up the code in this block would be appreciated.

 

[JOLTRON]

Something along the lines of

On a positive edge
If FlipFlop = 0 then FlipFlop = 1
Else FlipFlop = 0
Endif

This is a basic idea I don't have SCL but know basic idea.

Another place to look would be www.oscat.de open source programming concepts. They have a siemens file. I downloaded it before but it is all SCL so I can't view it. May be something helpfull in there.

 

[L D[AR2P#0.0]]

Post your SCL code. As there is no memory storage in a FC, you will have to pass the storage bit for your edge detection as an in/out variable.

 

[L D[AR2P#0.0]]

Here's an example FC

FUNCTION FC99: void
VAR_INPUT
        bRisingEdgeTrigger:BOOL;
end_var
VAR_in_out
    bToggle:BOOL;
    bEdgeStore:BOOL;    
end_var
;
IF bRisingEdgeTrigger AND NOT bEdgestore THEN bToggle:=NOT bToggle; END_IF;
bEdgeStore:=bRisingEdgeTrigger;
    
END_FUNCTION

 

[Peter Nachtwey]

Toggle:=Input AND NOT LastInput;
LastInput:=Input;
Run := Run XOR Toggle;

If you have R_Trig then

VAR
    R_TRIG0  :  R_TRIG;  (* Declare an R_TRIG instance *)
END_VAR

Run := Run XOR R_TRIG0(CLK:=Input); (* Flip the state *)

OT but related. I would prefer to have this:

Run := Run XOR R_TRIG(Input);

No extra declaration required. I hate having to assign parameters too like the IEC makes you do. The compiler should be smart enough to allocate a memory state for each instance of R_TRIG instead of having to declare it.

The general case should have been

R_TRIG(boolean expression)

where the boolean expression could be of any complexity.

 

[MrTysk]

Thanks for all your answers. Gonna test some now and I'll keep you updated how it goes.

 

[MrTysk]

Well I did it like this;

FUNCTION FC521 : VOID

VAR_INPUT
InP : BOOL;
END_VAR

VAR_OUTPUT
Out : BOOL;
END_VAR

BEGIN
IF InP THEN
IF Out THEN
Out := FALSE;
ELSE
OUT := TRUE;
END_IF;
END_IF;

END_FUNCTION

And then I put a -(P)- at InP in the whenenver I use the fc in my program. Works like a charm. Can't understand why I didn't think of that before.
Im pretty new on scl so there's much to learn. And thanks again for the replies. I learned some new things from that too.=)

 

[rwy34ils]

I use a counter to do the same thing. Set the counter to reset when accum=2. Each time the button is pressed, the counter will alternate between 0 and 1. Then use 'equal' compare instructions to test whether it is flipped (=1) or flopped (=0). This is ladder logic but it can be done in SCL too.

 

[L D[AR2P#0.0]]

Well I did it like this..... Works like a charm.

.... for now !

Your function contains two fundamental coding errors.

1. You are testing the state of an FC output before it has been conditioned.

2. The FC output is not being written all the time.

 

[MrTysk]

OK L D I'll look into this. Thanks for input

 

[JesperMP]

For logic code in SCL, avoid IF THEN ELSE if possible. Write logic as you would in LAD or FBD:
What I mean is, if you write logic like this:
var1 := var2 AND var3 AND NOT (var4 OR var5) ; etc...
then you dont have to worry about initialising variables. And as a bonus, the code is tighter and more readable (to my opinion).

FUNCTION FC_flip_flop : VOID
VAR_INPUT
    bi_input : BOOL; 
END_VAR
 
VAR_IN_OUT
    bi_oneshot_mem : BOOL ;
END_VAR
 
VAR_OUTPUT
    bi_toggle : BOOL; 
END_VAR
 
bi_toggle := bi_toggle XOR (bi_input AND NOT bi_oneshot_mem) ;
bi_oneshot_mem := bi_input ;
 
END_FUNCTION

 

[L D[AR2P#0.0]]

Jesper - You are also testing the state of an FC output before it has been conditioned.

 

[JesperMP]

Ouch. You are right LD.

FUNCTION FC_flip_flop : VOID
VAR_INPUT
bi_input : BOOL;
END_VAR
VAR_IN_OUT
bi_oneshot_mem : BOOL ;
bi_toggle : BOOL;
END_VAR
bi_toggle := bi_toggle XOR (bi_input AND NOT bi_oneshot_mem) ;
bi_oneshot_mem := bi_input ;
END_FUNCTION